Schematic top net name

[Vissu]

Hi,

If I've the context path from the top level schematic cellview, and a
lower level net/port, how do I get the top level net name? Is there a
SKILL function?

Thanks,
-Vissu

 

[Andrew Beckett]

On 10 Apr 2006 11:40:50 -0700, "Vissu" <vissub@gmail.com> wrote:

Hi,

If I've the context path from the top level schematic cellview, and a
lower level net/port, how do I get the top level net name? Is there a
SKILL function?

Thanks,
-Vissu

geGetAdjustedPath() is probably what you want. For example:

/*****************************************************************
* *
* (abGetHierNetName net @optional (window (hiGetCurrentWindow))) *
* *
* Given a net object, return the adjusted hierarchical net name. *
* By adjusted, we mean that the path is adjusted to the net name *
* at the highest level. *
* *
*****************************************************************/

(procedure (abGetHierNetName net @optional (window (hiGetCurrentWindow)))
(let (netName)
(setq netName
(strcat
"/"
(buildString
(foreach mapcar i (geGetHierMemInst window)
(dbGetMemName (dbGetq (car i) name) (cadr i)))
"/"
)
))
(setq netName
(if (netName=="/")
(strcat netName (dbGetq net name))
(strcat netName "/" (dbGetq net name))
))
(geGetAdjustedPath window netName)
))

Regards,

Andrew.