Place instance or Shape on any angle in Cadence

[vtcad]

I'm looking for a skill routine to place either an Instance or Set of
shapes at any specified angle (will be used for placing die inside
package at an angle), is there any code out there already.

thanks for the help,

 

[Martin Heller]

vtcad schrieb:

I'm looking for a skill routine to place either an Instance or Set of
shapes at any specified angle (will be used for placing die inside
package at an angle), is there any code out there already.

thanks for the help,

Hi,

You can place instances only at fixed angles of 0°,90°,180°,270°
(+mirroring). For rotating arbitrary shapes, you can use the leHiRotate
function (could be already bound to the "O" key).

BR,
Martin Heller

 

[Andrew Beckett]

On Wed, 01 Aug 2007 10:32:30 +0200, Martin Heller
<martin.heller@isit.fraunhofer.de> wrote:

vtcad schrieb:
I'm looking for a skill routine to place either an Instance or Set of
shapes at any specified angle (will be used for placing die inside
package at an angle), is there any code out there already.

thanks for the help,

Hi,
You can place instances only at fixed angles of 0°,90°,180°,270°
(+mirroring). For rotating arbitrary shapes, you can use the leHiRotate
function (could be already bound to the "O" key).

BR,
Martin Heller

The attached SKILL code was written for OA-enabled versions of the tools (e.g.
IC61) to illustrate how to rotate cells to arbitrary angles. It should also work
with IC5141 if you remove the stuff at the end which uses dbCreateMarker()
(since that function doesn't exist in CDB).

The idea is that it creates a pcell called "rotator", which you provide the lib,
cell, view, angle and magnification of the cell you want to place at an
arbitrary angle and magnification when you instantiate rotator.

Regards,

Andrew.

;------------------------------------------------------------------------
; This example illustrates how to implement a generic instance
; rotator with arbitrary angles.
;
; The code may not fully handle connectivity.
;
; If the master changes after the pcell has been evaluated, that will
; not be immediately reflected, as that would not trigger a pcell
; re-evaluation.
;
; This code is not intended to rotate pcells - that is best handled
; in the pcell itself, using the dbTransformCellView() function directly.
; If a pcell is rotated, only the default pcell parameters will be used.
;
; Andrew Beckett and Gilles Lamant
; 17th January 2006
;------------------------------------------------------------------------

pcDefinePCell(
list(ddGetObj("mylib") "rotator" "layout")

;----------------------------------------------------------------
; Formal parameters
;----------------------------------------------------------------
(
(angle 0.0)
(magnification 1.0)
(lib "")
(cell "")
(view "")
(nsides 16)
)

;----------------------------------------------------------------
; Code itself
;----------------------------------------------------------------
let((inst master success)
;----------------------------------------------------------------
; Do some sanity checking to ensure the placed cellView exists
;----------------------------------------------------------------
when(ddGetObj(lib cell view)
master=dbOpenCellViewByType(lib cell view)
when(master
;--------------------------------------------------------
; Create the instance and then flatten it to 32 levels
; of hierarchy
;--------------------------------------------------------
inst=dbCreateInst(pcCellView master "" 0:0 "R0")
dbFlattenInst(inst 32 t t)
;--------------------------------------------------------
; Some shape types (ellipses) do not rotate as expected,
; so need to convert them to polygons
;--------------------------------------------------------
foreach(shape pcCellView~>shapes
case(shape~>objType
("ellipse" dbConvertEllipseToPolygon(shape nsides))
)
)
dbCreateLabel(pcCellView "text" 0.0:0.0
sprintf(nil "Ang:%g Mag:%g" angle magnification)
"lowerLeft" "R0" "stick" 1.0)
;----------------------------------------------------------------
; Transform the whole cellView, using an arbitrary magnification
; and angle
;----------------------------------------------------------------
dbTransformCellView(pcCellView magnification angle)
success=t
) ; when
) ; when
;----------------------------------------------------------------
; Place a marker if the cellView cannot be opened
;----------------------------------------------------------------
unless(success
getWarn()
dbCreateMarker(
pcCellView
sprintf(nil "Cellview %L/%L/%L cannot be opened" lib cell view)
"pcellRotator"
list(0:0 0:1 1:1 1:0)
nil
t t "error"
) ; dbCreateMarker
) ; unless
) ; let
) ; pcDefinePCell
--
Andrew Beckett
Senior Solution Architect
Cadence Design Systems, UK.