LTSpice simulation error using downloaded BF998 model from NXP...

[server]

message unavailable

 

[Jones Joy Panicker]

Found this useful after six years. Thanks!

On Sunday, June 15, 2014 at 9:38:05 PM UTC+1, m...@iae.nl wrote:

L=0.12n should simply be \"0.12n\".
Vg1 is missing a dc value.
What\'s that .prm file?
The .asy file should link to the bf998.sub.

Works for me.

-marcel

-- bf998.sub ---------------------------------------------------
* BF998 SPICE MODEL OCTOBER 1993 PHILIPS SEMICONDUCTORS
* ENVELOPE SOT143 (R)
* 1.: SOURCE; 2.: DRAIN; 3.: GATE 2; 4.: GATE 1;
.SUBCKT BF998 1 2 3 4
L10 1 10 0.12N
L20 2 20 0.12N
L30 3 30 0.12N
L40 4 40 0.12N
L11 10 11 1.20N
L21 20 21 1.20N
L31 30 31 1.20N
L41 40 41 1.20N
C13 10 30 0.085P
C14 10 40 0.085P
C23 20 30 0.085P
C24 20 40 0.005P
D11 42 11 ZENER
D12 42 41 ZENER
D21 32 11 ZENER
D22 32 31 ZENER
RS 10 12 100
MOS1 61 41 11 12 GATE1 L=1.1E-6 W=1150E-6
MOS2 21 31 61 12 GATE2 L=2.0E-6 W=1150E-6
.MODEL ZENER D BV=10 CJO=1.2E-12 RS=10
.MODEL GATE1
+ NMOS LEVEL=3 UO=600 VTO=-0.250 NFS=300E9 TOX=42E-9
+ NSUB=3E15 VMAX=140E3 RS=2.0 RD=2.0 XJ=200E-9 THETA=0.11
+ ETA=0.06 KAPPA=2 LD=0.1E-6
+ CGSO=0.3E-9 CGDO=0.3E-9 CBD=0.5E-12 CBS=0.5E-12
.MODEL GATE2
+ NMOS LEVEL=3 UO=600 VTO=-0.250 NFS=300E9 TOX=42E-9
+ NSUB=3E15 VMAX=100E3 RS=2.0 RD=2.0 XJ=200E-9 THETA=0.11
+ ETA=0.06 KAPPA=2 LD=0.1E-6
+ CGSO=0.3E-9 CGDO=0.3E-9 CBD=0.5E-12 CBS=0.5E-12
.ENDS BF998
-- test.net --------------
* C:\\spice\\mhx\\bf998\\test.asc
VG2 N002 0 4 Rser=0
VG1 N003 0 0.1
VDS N001 0 5 Rser=0
XU1 N001 0 N002 N003 BF998
.dc VG1 -1 1 0.1
.lib BF998.sub
.backanno
.end